업무차 외부에 나가는 경우 해당 장소에서 ip를 셋팅해서 사용하다
다시 사무실로 들어온 후 ip를 원복하는 것이... 외근이 많은 나로써는 일이다...
netsh 기능을 이용하여 좀 더 수월하게 하는 방법을 찾아봤다.
일이 프로그래머라 그런가... 화면 만들고 뭐하고... 하는 것이 귀찮아 dos script로 만들어 봤다.
XP 에서는
netsh -c interface dump 기능을 이용했었는데...
win7에서는 해당 기능을 사용했을 때 누락되는 정보와 한글 영문으로 충돌나는 경우가 발생을 한다.
해서 간단히 다시 만들었다.
첨부된 파일... (아래 내용) 을 system32 와 같은 곳에 둔 후 도스창을 열어
makeip 사무실 192.0.0.2 255.255.255.0 192.0.0.1 210.94.0.7
이런식으로 하면 내 네트웍카드의 설정이 바뀐다.
그리고 해당 설정파일이
D:\ipchange\사무실.bat
로 남는다
나중에 다른 ip로 바꾸었다가 다시 사무실로 들어가는 경우 해당 directory의 사무실.bat를 실행하면 된다.
makeip.bat 내용이다.
@echo off
if "%1" == "" goto SHOWMSG
if "%2" == "dhcp" goto DHCP
if "%2" == "" goto SHOWMSG
if "%3" == "" goto SHOWMSG
if "%4" == "" goto SHOWMSG
if "%5" == "" goto SHOWMSG
echo netsh interface ip set address name="로컬 영역 연결" source=static addr=%2 mask=%3 gateway=%4 gwmetric=1 > d:\ipChange\%1.bat
echo netsh interface ip set dns name="로컬 영역 연결" source=static addr=%5 register=primary >> d:\ipChange\%1.bat
if not "%6" == "" echo netsh interface ip add dns name="로컬 영역 연결" addr=%6 index=2 >> d:\ipChange\%1.bat
if not "%7" == "" echo netsh interface ip set wins name="로컬 영역 연결" source=static addr=%7 >> d:\ipChange\%1.bat
goto EXEC
:DHCP
echo netsh interface ip set address name="로컬 영역 연결" source=dhcp > d:\ipChange\%1.bat
echo netsh interface ip set dns name="로컬 영역 연결" source=dhcp >> d:\ipChange\%1.bat
goto EXEC
:SHOWMSG
cls
echo -------------------------------------------------
echo makeip 이름 ip mask gateway dns1 dns2 wins
echo -------------------------------------------------
echo 이름 : 저장할 파일명
echo ip : ip address
echo : dhcp (자동설정일 경우)
echo mask : subnet mask
echo gateway : gateway
echo dns1 : 기본 dns
echo dns2 : 보조 dns (option)
echo wins : 기본 wins (option)
echo -------------------------------------------------
echo made by sbkyun@gmail.com
echo.
echo.
goto END
:EXEC
echo 설정한 ip를 설정합니다.
echo.
echo.
pause
d:\ipChange\%1.bat
:END
댓글 없음:
댓글 쓰기